IchigoJamを使ってID-31の周波数をテレビの画面に拡大表示してみた

IchigoJamとアマチュア無線で「IchigoHam」ネタです。

子供用マイコンIchigoJamを使って、アイコムの無線機ID-31をCI-Vプロトコルで外部制御し、周波数などを（IchigoJamのビデオ出力から）テレビ画面に拡大表示をしてみました。

先ずは動画をご覧ください。

さらに、無線機へ外部から操作できるようにするとかして本格的にしたら、高齢者フレンドリーな用具として実用的になるかも知れませんね。
また、かねてから目標としていたモービル（車）のカーナビに拡大表示（関連記事）も実現できそうです。

IchigoJamで（しかも公開版＝Ver.1.2.3＝で、機械語も使わずに）、CI-Vのプロトコル制御がとりあえずできたので、更にいろいろな無線機の用途が試せそうです。IchigoJamとアマチュア無線で「IchigoHam」の世界ですね。

－・・・－

以下に備忘録を兼ねてメモします。
（まねをされる場合は自己責任でお願いします。また、ノイズや高周波回り込みの配慮はしていません。また、複数のCI-V接続は未対応です。）


・ID-31の設定：

CI-Vアドレスはモデル毎に異なるので確認。
ID-31は#84。プログラムの10行目で変数Dの値に。


ボーレートを4800に変更。
プログラム20行目のBPSと同一にする。


トランシーブは”ON”に設定。

・接続ケーブル：

参考記事
続：ID-51/31のCI-V取り出し用変換ケーブル
スピーカージャックの中点がCI-VのI/O信号。
外付けスピーカーが必要となる。
（今回はスピーカーマイクを接続した）

CP2102を使ったUSB CI-Vインターフェース
回路は上の記事と同じ。
ダイオード（1N4148）のカソードをTXDに、アノードをRXD接続、RXDからCI-VのI/O信号へ。
なお、ダイオードなし（TXDとRXDショート）でも一応は動作したが、CI-Vのパラ接の時は注意必要。

・プログラム：

IchigoJam BASIC 1.2.3 by jig.jp
OK
load0
Loaded 704byte
OK
list
5 'CI-V MONITOR
10 D=#84:'id-31
20 UART 0,1:BPS 4800:CLS:CLV:VIDEO 3
30 UART 1,0:LC 0,-1:PRINT CHR$(#FE);CHR$(#FE);CHR$(D);CHR$(#E0);CHR$(#03);CHR$(#FD);:UART 0,1:GOSUB 100
40 UART 1,0:LC 0,-1:PRINT CHR$(#FE);CHR$(#FE);CHR$(D);CHR$(#E0);CHR$(#04);CHR$(#FD);:UART 0,1:GOSUB 100
50 GOSUB 100
60 GOTO 40
100 I=0
110 A=INKEY():IF NOT A CONT
120 A=A&#FF:[I]=A:I=I+1:IF I>2 GOTO 140
130 IF A<>#FE GOTO 100
140 IF A<>#FD GOTO 110
150 IF [4]=0 OR [4]=3 GOTO 200
160 IF [4]=1 OR [4]=4 GOTO 300
200 LC 0,5
210 PRINT HEX$([9],1);HEX$([8],2);".";HEX$([7],2);"MHz"
220 RETURN
300 LC 0,3
310 IF [5]&#FF=5 AND [6]&#FF=1 PRINT "FM  "
320 IF [5]&#FF=5 AND [6]&#FF=2 PRINT "FM-N    "
330 IF [5]&#FF=#17 ? "DV  "
340 RETURN
OK

・その他：
プログラムはSAVE0をしておき、ボタンを押しながら電源ON(即ち、0番プログラムの自動実行）で起動させること。（起動後、すぐにUART受信をOFFにするため。）
そうしないと、無線機との電源投入順によっては、無線機からの信号をIchigoJamがキー入力として受け付けて暴走する場合がある。

追記：この暴走の解決策のアドバイスをいただきました。回路とプログラム変更で暴走防止対応ができました。こちらの　IchigoJam用CI-Vインターフェースの改善を参照ください。


#自作室 #CI-V #電子工作 #アマチュア無線 #IchigoJam #IchigoHam

---