ミニマムJAM-R 出図完了！

ミニマムJAM-R、出図完了しました！

・前回の記事で予告したIchigoJam R互換の組み込み用小型版基板です。

・その他のミニマムJAMについてはこちらをご参照ください。


※IchigoJam は 株式会社jig.jp の登録商標です。

#IchigoJam #IchigoHAM #自作室

---

　　　　

IchigoJam R β - 着弾！！

予約していた新製品IchigoJam R β版が先ほど届きました！

RISC-Vで、従来版よりかなり強化されているそうで、IchigoHAMの用途が広がります。 特に、 ・10倍高速処理
・アナログ入力ポートが 4ポートに
・DAC(デジタルtoアナログ変換）搭載
・親しみやすいBASIC（インタププリタ）に加え、コンパイラも充実し、さらに高速処理がも可能
といったことが、IchigoHAMには嬉しいです。

追々、色々試して見ようと思います。
組み込み用の小型基板(ミニマムJAM R)も作ろうかと思案中です。

※IchigoJamは(株)Jig.jpの登録商標です。
#IchigoHAM #IchigoJam #自作室

---

　　　　

LEDテープでモールス狼煙（のろし）を作ってみました。

通信の原点は「モールス信号」と言いたいところですが、古代に遡ると通信の原点は「狼煙（のろし）」ではないでしょうか？　てなことを思いながらLEDテープを狼煙にみたてた「モールス狼煙」をつくってみました。

まずは、動画をご覧ください。



キーボード入力文字、固定メッセージをがモールス符号に変換されてテープ上をがっていきます。動画にはありませんがパドル打ちにも対応しています。

実は、このモールス信号狼煙は、以前に作っていて今年の関ハムシンポでデモをしたのですが、その時はLEDが32個（x2回繰り返し）だったのですが、今回はLED119個で全長4ｍにグレードアップしました。これは、使用しているマイコンのIchigoJam Basic（正確にはIchigoCake Basic)がバージョンアップされたおかげで狼煙らしく見えるようになりました。

今回のハードウェアについて：

・自作のミニマム・ジャム基板の内、拡大版にも対応したミニマム・ジャム・ターボ基板にマイコンチップは1ランク上のLPC1115FBD48/303（64KB flash)を実装。クリスタルの実装は割愛（本当は実装した方が良い）、5Ｖ→3.3Ｖの3端子も実装せず3.3Ｖで駆動。ファームウェアはIchigoCake Basic V1.4を書き込み。

・ミニマムJAMは、自作の変換基板を介して、IchigoIgai(お子さんに人気のIchigoDake用のドッグ）をヤドカリして、LCDモニターとキーボードに接続。（最初はキーボードの動作が不安定※でしたがIchigoDakeのキーボード端子は抵抗でプルアップ強化して解決しています。（※おそらく、GND線の引き回しの影響と推測。）

・WS2812B LED Tape（5ｍロール/150LEDs)のDin端子とGNDをミニマムジャムのLEDとGND端子に、電源（+5VとGND)は大容量モバイルバッテリーに接続。
（結構電流が流れるので、JAMやIgai経由の電源供給では無理がありました。）

プログラムについて

・2月の関ハムシンポでデモで使ったIchigoJam用に作ったプログラムを修正して使用しています。IchigoJamでは最大1KBの制限の為、3プログラムに分割していましたが、IchigoCake Basicは8KBまでプログラムできるので1本のプログラムでおさまります。また配列変数の個数も増えた分だけLED個数を増やし、結局119個のLEDを使用しています。

・全プログラムリスト

10 @ARUN:'201019MorseNoroshi(for Cake 1.40)
20 '
30 POKE#700,107,82,0,0,0,40,94,54,109,34,42,115,97,85,50,63,47,39,35,33,32,48,56,60,62,120,0,0,49,0,76,90,5,24,26,12,2,18,14,16,4,23,13,20,7,6,15,22,29,10,8,3,9,17,11,25,27,28
40 POKE#73A,84,85,0,23,59,5,9,55,40,11,51,7,22,45,59,5,9,55,40,20,52,17,27,31,53,58,61,46,30,6,18,22,43,36,10,26,16,29,19,24,57,28,2,12,25,37,3,49,50,11,51,7,8,14,54,15,21,13,42,4,38
50 '
60 CLS:VIDEO3:?"Morse Noroshi 2"
70 KBD1:CLV:S=5:V=50:T=720:GSB@WS
80 '
90 @KB:?"KEY =";:CLT
100 GSB@WS:K=INKEY():I=IN(1):J=IN(4):IF TICK()>T GOTO@AUTO ELSE IF !(K=8 OR (K>32 AND K<91) OR K=127 OR (K>162 AND K<224))AND (I AND J) CONT
110 X=RND(V):Y=RND(V):Z=RND(V)
120 IF !I OR !J GOTO@PADDLE
130 L=9
140 IF K=8 OR K=127 M=256:? "xx";:GOTO 200
150 IF K>161 A=K-105 ELSE A=K-33
160 M=PEEK(#700+A)
170 IF !M GOTO 100
180 ? CHR$(K);" ";
190 IF!(M&256) M=M<<1:L=L-1:CONT
200 M=M<<1:L=L-1
210 IF !L ?:GSB@W2:GOTO@KB
220 BEEP 13,99
230 IF !(M&256) ?CHR$(#A5);:GSB@W1 ELSE?"-";:GSB@W1:GSB@WS:GSB@WS
240 BEEP 0:GSB@W0:GOTO200
250 '
260 @PADDLE:?"*PADDLE*"
270 IF !I BEEP 13,99:GSB@W1::BEEP0:GSB@W0
280 IF !J BEEP 13,99:GSB@W1::GSB@WS:GSB@WS:BEEP 0:GSB@W0
290 I=IN(1):J=IN(4)
300 IF !I OR !J GOTO270ELSE GSB@W2:GOTO@KB
310 '
320 @AUTO:?:?"*AUTO DEMO*":V=50:S=7:T=7
330 'MSG="CQCDEICHIGOHAM"
340 POKE#780,#43,#51,#43,#51,#44,#45,#49,#43,#48,#49,#47,#4F,#48,#41,#4D,#00
350 C=#780
360 IF INKEY() OR !IN(1) OR !IN(4) GOTO @KB
370 X=RND(V):Y=RND(V):Z=RND(V)
380 K=PEEK(C):C=C+1
390 IF !K WAIT T:GOTO350
400 L=9
410 IF K=8 OR K=127 M=256:? "xx";:GOTO 470
420 IF K>161 A=K-105 ELSE A=K-33
430 M=PEEK(#700+A)
440 IF !M GOTO360
450 ?"AUTO:";CHR$(K);" ";
460 IF!(M&256) M=M<<1:L=L-1:CONT
470 M=M<<1:L=L-1
480 IF !L ?:GSB@W2:GOTO360
490 BEEP 13,99
500 IF !(M&256) ? CHR$(#A5);:GSB@W1: ELSE?"-";:GSB@W1:GSB@WS:GSB@WS
510 BEEP 0:GSB@W0:GOTO470
520 '
530 @W1:LET[0],X,Y,Z:GOTO@WS
540 '
550 @W2:GSB@W0
560 @W0:LET[0],0,0,0
570 @WS:WS.LED 119:COPY #DFD,#DF7,-504:COPY #C05,#8CB,-6:COPY #8CB,#8C5,-198:WAIT S:RTN

詳細説明は割愛しますが、モールス符号変換方式についてはこちらの記事をご参照下さい。
また、2月にデモをしたエレキーから狼煙を送出（IN1とIN4にパドルを接続）のプログラムも残しています。（今回は接続検証をしていませんが）

以上、何かのご参考になれば幸いです。

※IchigoJamは(株)Jig.jpの登録商標です。
#IchigoJam #IchigoHAM #自作室

---

　　　　

モールス オウム返し by IchigoJam

ボタンを押したら、そのとおりにオーム返しする、名付けて「モールスオウム返し」プログラムをIchigoJamで作りましたのでご紹介します。

先ずは動画をどうぞ。

◆IchigoJamでオウム返し

このようにIchigoJam単体でも遊べます。

◆ミニマム版

最小構成のハードウェアでミニマム化し、ユニバーサル基板で配線してFRISKケースに納めました。また、電鍵用ジャックも付けてボタンと共に電鍵にも反応するようにしています。

◆プログラム

折角なので、普通に電源ONしたら押したら鳴るだけのモールス練習機になり、ボタンか電鍵を押しながら電源ONしたらオウム返しのプログラムが起動するようにしています。

なお、IchigoJamのバージョンは1.4.1を使用しています。PCからシリアル転送で書込みました。（二つ目動画の最後の写真をご参照）

・プログラムリスト＃0

10 @ARUN:'MORSE OSC.
20 IF BTN() LRUN 1
30 BEEP 6,12:WAIT 12
40 IF !BTN() CONT ELSE BEEP 9,99
50 IF BTN() CONT ELSE BEEP 0
60 GOTO 40

40、50、60行はモースル練習機(音の発振器）の3行プログラムです。
10、20、30行で、電源ON 時にボタンがオンなら次の1番のプログラムを起動します。
これをSAVE0してプログラムを0番に保存します。


・プログラムリスト＃1

続いて、オウム返しするプログラムです。

10 'MORSE PARROT
20 BEEP 6,4:WAIT 8:BEEP 6,12:WAIT 24
30 I=0:CLT
40 IF I AND TICK()>90 J=I:GOTO100
50 IF I>99 BEEP 6,12:WAIT 90:GOTO 100
60 IF !BTN() GOTO 40
70 [I]=TICK():CLT:I=I+1:BEEP 13,99:LED 1
80 IF BTN() CONT ELSE BEEP 0:LED0:[I]=TICK():CLT:I=I+1
90 GOTO 40
100 J=I
110 FOR I=1 TO J STEP 2
120 BEEP 9,99:LED 1:WAIT[I]
130 BEEP 0:LED 0:WAIT[I+1]
140 NEXT
150 GOTO 30

これをSAVE1で1番に保存します。


◆回路図

ミニマム版の回路図です。

なお、サウンド端子から抵抗内蔵トランジスタを介してスピーカを鳴らしていますが、スピーカーが超小型で３V電池駆動のせいか、それほど大きな音は鳴っていません。

◆実装写真(ミニマム版）

◆まとめ
ちょっとしたゲームや、ひとりモールス練習などに参考にしていただければ嬉しいです。いつものことですが真似をされる場合は自己責任でお願いしますね。

#IchigoHAM #IchigoJam #自作室 #CW

---

　　　　

関西ハムシンポジウム2020 に参加しました。

本日、関西ハムシンポジウム（於：尼崎・ARIC)に参加しました。


久しぶりの関ハムシンポで、しかもジャンク市出展での参加です。今回は、ユニバーサル基板やジャンク品に加えて、初めての試みとしてIchigoHAM自作品の参考展示もしました。

先ずは、写真をどうぞ。

ブースからの全景パノラマ

結構、来場者は多かった

出店ブースの「モースル信号狼煙」(LEDテープ使用）

CI-V制御で無線機連携（周波数表示）のデモ

モールス練習機（おうむ返し版）とFRISKタッチキーヤーも展示

正直言って、ハムイベントでIchigoJamは場違いでスベル？ことも覚悟していたのですが・・・

・・・なんのなんの・・・

予想外に多くの方々が、IchigoJamをご存知、もしくは、既に持っておられていて、
IchigoJamでキーボードキーヤーや、CI-Vの無線機制御ができると知ってビックリされたり、IchigoJamをFOXハンティング(ARDF?)のビーコンに活用されていたり、任意の文字画像をATVに合成を試みたといったOMさんのお話も。

また、IchigoJamをご存知ない方も、うん十年ぶりにBASIC言語のLISTを見て、急に若返った(失礼！）方も。

今回は自作品の参考展示でしたが、皆様から、貴重なフィードバックやご意見をたくさん頂きました。今後の参考にさせていただきたいと思います。


会場では、話題のICOMの新製品IC-705の実機展示されていましたが、自ブースを空けられないので、チラ見が出来ただけでさわり倒せずで残念でした！

写真だけでもは撮ればよかったのに　と反省！。

（下の写真はむせんZone25(無線機屋さん）のページから）

また、尋ね人？(3年前から探していたGaAs FET基板ご所望のOMさん）とも無事再会でき、頼まれた基板を無事お渡しできました。

他にも、昔からお世話になっていた方々と久々の再会できたり、自作をFBに楽しんでおられる方々とも出会えて、とても嬉しく 有意義な一日を過ごさせていただきました。

アイボールいただいた局長さん、どうも、ありがとうございました。

#ハムライフ#自作室 #IchigoHam #IchigoJam

---

　　　　

失敗！ ピッチ変換基板を買い忘れました。

ちょっと進捗が滞っているIchigoHAMのアクティビティー、表示素子をどうするかで悩んで固まっていたのですが、これがちょうど良いのでは！と通販で買いました。

「I2C接続小型キャラクタLCDモジュール 8x2行」これなら文字も大きめですので。

ところがところが、リード(足)のピッチは1.5mmで基板に実装できません。変換基板付のピッチ変換付キットのほうを買うべきでした。失敗！失敗！です。

変換基板だけ注文するか、いっそのこと基板を起こすか、いずれにせよ、なかなか進捗しません。

#IchigoHAM #IchigoJam #自作室

---

　　　　

アナログメーターをIchigoJamで駆動してみた (動画有り)

結線２本、プログラム一行でここまで動きました。

Analog meter driven by IchigoJam

いろいろと遊べそうです。

追記）メーターとOUT2を直結しましたが、平滑用のコンデンサ+抵抗を付けるほうが良いですね。メーターの悲鳴が聞こえてきそうです。

追記2）平滑回路を追加した続篇の記事をアップしました。→　こちらをご覧ください。

#IchigoJam #IchigoHAM #Sメーター #自作室

---

　　　　

IchigoJamでCWキーヤー(4の次の番外編)：OLEDをつけてみましたが・・・

アマチュア無線仲間の方々がIchigoJamに興味を持ってくれたらいいな、と思いながら書いているシリーズ記事。今回はちょっとお話が脱線します。
次回は、前回の記事に続いて、キーボードキーヤーを作る予定ですが、せっかくなので、先に基板に表示を付けてしまおうと、構想通りに0.96インチOLEDを実装して、試しに表示をさせてみたのですが・・・

なかなかくっきりきれいな表示ではあるのですが・・・

ん～ン、文字が小さすぎて読めない！　（って何かのCMですね。）

ソフトを工夫して倍角のフォントで表示するようにするか、あっさり予定を変更して、文字の大きな2行表示の液晶に付け替えるか、ちょっと悩んでいます。

機能も増えてきてそろそろプログラムのサイズも気にしないといけないし、どうしようかと。

ー・・・ー　

　IchigoJamでCWキーヤーの総目次 へ

　

#IchigoJam #IchigoHam #自作室

---

　　　　

IchigoJamでCWキーヤー(4)：メッセージキーの追加とコールサインの自動送出

アマチュア無線仲間の方々がIchigoJamに興味を持ってくれたらいいな。
そんなことを思いながら、自分流のエレクトリックキーヤーを作り上げていく記事を連載風に書いています。今回がその第3回目になります。

前回は、パドルとリグをつなぐインターフェス回路と、キーヤーのプログラムをご紹介しました。
今回は、固定メッセージ（自局のコールサインなど）の送出する機能を追加します。

◆基板(今回実装分）
固定メッセージを送出するタクトスイッチを追加しました。
折角なので４つのスイッチを追加し、前回のキー速度UP／DOWNスイッチと併せて６つのスイッチになりました。

表（部品）面

左から、UP：緑のスイッチ：キー速度を早く、DOWN：青：遅く、メッセージ１（茶）、２(赤)、３(橙)，４(黄)

裏（半田）面


IchigoJam S に挿入した写真

左側の木製の当局愛用の「どこでもパドルMINI Wood 」by のむさんローテク工房　です。

◆回路図
赤線で囲んだ部分が今回実装追加した回路です。

（クリックすると拡大します）

◆回路の説明
前回のUP/DOWNスイッチと同様にIN2の１ポートでアナログ分圧方式を採用し、（今回４つのスイッチが増えて）計６つスイッチを抵抗で分圧された電圧をプログラムで判定します。この回路は、アマチュア無線家らしくICOM社の無線機用外部キーパッドの回路定数に倣いました。
（参考：IchigoJamに無線機用外部キーパッドをつないでみました(Part 1)）

◆部品リスト(今回追加した部品のみ）

部品番号	名称	型番	備考
SW_1~４	タクトスイッチ	(6x6mm)	2.54mmピッチに挿入できるもの
R6	1/6W カーボン抵抗	1.5kΩ
R7	1/6W カーボン抵抗	1.5kΩ
R8	1/6W カーボン抵抗	2.2kΩ
R9	1/6W カーボン抵抗	4.7kΩ

◆プログラム

10 '190828 CW KEYER(4)

20 GOSUB @INIT

30 IF !IN(1) OUT 1,1:LED 1:BEEP 13,T:WAIT T:OUT 1,0:LED 0:WAIT T

40 IF !IN(4) OUT 1,1:LED 1:BEEP 13,T*3:WAIT T*3:OUT 1,0:LED 0:WAIT T

50 GOSUB @SW:IF S=0 GOTO 30

60 IF S<5 GOTO @MORSE

70 IF S=6 T=T-1 ELSE T=T+1

80 IF T<2 T=2

90 IF T>18 T=18

100 IF IN(1) AND IN(4) BEEP 50,T:WAIT 2*T:GOTO 30

110 @MORSE:C=S*10

120 N=[C]:IF N=0 GOTO 30

130 B=10000:FOR I=0 TO 4:M=N/B%10:IF M<0 M=M+6:N=N+35536

140 IF M OUT 1,1:LED 1:BEEP 13,T*M:WAIT T*M:OUT 1,0:LED 0:WAIT T

150 B=B/10:NEXT

160 WAIT T*3:C=C+1:GOTO 120

170 @SW:V=ANA(2)

180 IF V>933 S=0:RTN

190 IF V<932 S=4

200 IF V<784 S=3

210 IF V<663 S=2

220 IF V<511 S=1

230 IF V<303 S=5

240 IF V<92 S=6

250 RTN

260 @INIT:T=5:LET[10],1333,333,11133,331,3111,311,0

270 LET[20],113,131,11111,31,31,3111,313,0

280 LET[30],3313,111,1311,0

290 LET[40],3,113,0

300 RTN

◆プログラムの説明
・30行から100行：前回のキーヤー部分です。これにメッセージキーヤーを追加していきました。

・170行の＠SWサブルーチンは、IN2のアナログ電圧を判別してどのスイッチも押されていない時は変数Sに０を、押されているときは押されたスイッチの番号（１～６）をSに 返します。なお、便宜上UPスイッチは５、DOWNスイッチには６を割り当てています。

・20行と260行～300行：
　固定文字列(メッセージ)のモールスコードを定義しています。今回は、短点（・）を１、長点（－）を３として、”JO3”の場合は、1333＝・－－－＝”J”  333=－－－＝”O” 11133=・・・－－＝”３”といったわかりやすい方式（※１）を採用しました。おしまいには０を入れます。
260行で配列の[10]からにはSW_1が押されたときに送出する文字列を、270行に[20]からはSW_2の文字列といった具合に入れていきます。今回のプログラムでは、次のようにしていますが、好きなメッセージに変更できます。

行	配列	文字列	おしまい
260	[10]～	1333(J), 333(O),11133(3),331(G),3111(B),311(D)	0
270	[20]～	113(U),131(R),11111(5),31(N),31(N),3111(B),313(K)	0
280	[30]～	3313(Q),111(S),1311(L)	0
290	[40]～	3(T),113(U)	0

・110行から160行：
　前述のエンコードした数字をモールス符号化するプログラムです。
このわかりやすい単点１、長点３の方式とプログラムはIchigoJam開発者の福野さんのブログ記事：音声読み上げで自学する和文モールス信号 on IchigoJamから頂きました。
IchigoJamのBASICに慣れ親しんでいただく目的でこのわかりやすい方式を紹介させていただきました。

一方で、実践面で必要な”？”や”/”といった6要素のモールス符号には対応していないので、次回以降ではとてもわかりにくい方式？への変更を予定していますので悪しからずご了承ください。

次回は、キーボードで入力した文字でモールス信号を送出してみたいと思います。

ー・・・ー　

　IchigoJamでCWキーヤーの総目次 へ

　


#IchigoJam #IchigoHam #自作室

---

　　　　

IchigoJamでCWキーヤー(3)：無線機との接続と速度調節キー

アマチュア無線仲間の方々に、IchigoJamに興味を持ってもらいたい！
そんなことを思いながら、自分流のエレクトリックキーヤーを作り上げる連載記事の第3弾です。

前回、インターフェースの全回路構想をご紹介しました。（下の写真）

前回は基板の上に部品を並べてみただけでした。(上の写真）今回は、そのうちのキーヤーと無線機を接続する回路と、キーヤーの速度調整ができるスイッチの部分を 自作したIchigoJamに上乗せできるユニバーサル基板 に実装をして、実際に無線機のキー入力につないでテストをしました。（今後、この基板に回路/機能を順次増やしていく予定です。）

◆基板(今回実装分）

表（部品）面


裏（半田）面


IchigoJamに挿入した写真
左のジャックがパドル入力(パドルへ）、右がキー出力(無線機のキー入力へ） 
緑のスイッチがキー速度を早く(UP)、青が遅く(DOWN)


無線機（IC-7100）のキージャックにつないでキーイング中

◆回路図
今回実装分の回路です。

（クリックで拡大します）

◆回路の説明
パドル入力は(1)：初めの第一歩 - ３行のプログラムと同じくIN1とIN4端子ですが、今回は3ピンのフォーンジャックも取付けて、念のためでプルアップ（R1,R2の22kΩの抵抗）しています。
（IN1とIN4はチップ内でプルアップされているので抵抗が無くても動作しますが、ノイズマージン向上のおまじないと思ってください。）

キー出力は、同じ3ピンジャックを2ピンで使用し、手持ちのフォトカプラ―で無線機とIchigoJamをアイソレートして高周波回り込みへの配慮をしました。（出力回路はこちらのようなトランジスタ回路でも動作はします。）
なお、今回実装した部品ではキー出力のオン抵抗が100Ω台になっており、無線機の種類や結線構成（例：マイク端子からのキー入力）によっては不具合の恐れもあるので、フォトカプラと抵抗はICソケットを介しての実装し、後から交換ができるようにしました。
（今回使用したIC-7100は数十kΩまで反応しますので、オン抵抗は全く問題が無いのですが。）
無線機のキー入力したときは、無線機からもモニター音がでるので、IchigoJamのブザー音を消せるようにスイッチ(SW_SOUND)を設けました。

キーイング速度変更はUPとDOWNのタクトスイッチ方式にしました。速度変更はボリューム(半固定抵抗)を使う方法もありますが、今回はさらに多くのスイッチをつける予定があるのでIN2のアナログ入力の１ポートでアナログ分圧方式でスイッチの判定をします。（参考：IchigoJamに無線機用外部キーパッドをつないでみました(Part 1)


◆部品リスト

部品番号	名称	型番	備考
J1,J2	3.5ｍｍ小型ステレオミニジャック 基板取付用	ST-005-G	基板の穴をドリルで大きくする
J3	ピンソケット	4ピン
R1,R2	1/6W カーボン抵抗	22kΩ
R3	1/6W カーボン抵抗	330Ω	（無線機によっては要変更）
U1	フォトカプラ	TLP785	手持ちのものでランク不明 （無線機によっては要変更）
SW_UP, SW_DOWN	タクトスイッチ	(6x6mm)	2.54mmピッチに挿入できるもの
R4	1/6W カーボン抵抗	2.2kΩ
R5	1/6W カーボン抵抗	470Ω
SW_SOUND	スライドスイッチ	( 3P)	2.54mmピッチ
BZ1	圧電サウンダ
	ユニバーサル基板		IchigoJam用（自作品）

◆プログラム

・3行プログラム

10 IF !IN(1) OUT 1,1:BEEP 9,5:WAIT 5:OUT 1,0:WAIT 5
20 IF !IN(4) OUT 1,1:BEEP 9,15:WAIT 15:OUT 1,0:WAIT 5
30 GOTO 10

初めの第一歩 - ３行のプログラムを少し変更しました。OUT1,1でキー出力 ON(電鍵を押した状態）、OUT1,0 でOFF(電鍵を離した状態)になります。
このプログラムだけでも、無線機を接続したらIchigoJamのキーヤー操作で実際に電波が出ていきます。

・キーイング速度調節の追加

10 T=5
20 IF !IN(1) OUT 1,1:LED 1:BEEP 13,T:WAIT T:OUT 1,0:LED 0:WAIT T
30 IF !IN(4) OUT 1,1:LED 1:BEEP 13,T*3:WAIT T*3:OUT 1,0:LED 0:WAIT T
40 S=ANA(2):IF S>200 GOTO 20
50 IF S<50 T=T+1 ELSE T=T-1
60 IF T<2 T=2
70 IF T>18 T=18
80 IF IN(1) AND IN(4) BEEP 50,T:WAIT 2*T
90 GOTO 20

キーヤーの送出速度をスイッチ操作で変更できるようにしました。
? ANA(2)で確認したら、UPスイッチを押した時はANA(2)は0、DOWNスイッチを押した時は178か179、どちらも押していない時は1023になりましたので、おおざっぱに50と200で判定してスイッチを判定しています。速度調節の上限と下限に制限（2と18）も設けました。
ついでにキー出力に合わせてLEDが点滅するようにしました。

欲を言えば、速度調節の加減(スイッチ押した時の速度変化量）に違和感がありますが、さほど細かに調整はしないので、良しとしています。

次は、固定メッセージ（自局のコールサインなど）の送出機能を追加する予定です。

ー・・・ー　

　IchigoJamでCWキーヤーの総目次 へ

　


#IchigoJam #IchigoHam #自作室

---